### Section 4.5
CSG Objects

Constructive Solid Geometry, CSG, is a powerful tool to combine primitive objects to create more complex objects as shown in the following sections.

### Section 4.5.1
What is CSG?

CSG stands for Constructive Solid Geometry. POV-Ray allows us to construct complex solids by combining primitive shapes in four different ways. These are union, where two or more shapes are added together. Intersection, where two or more shapes are combined to make a new shape that consists of the area common to both shapes. Difference, where subsequent shapes are subtracted from the first shape. And last not least merge, which is like a union where the surfaces inside the union are removed (useful in transparent CSG objects). We will deal with each of these in detail in the next few sections.

CSG objects can be extremely complex. They can be deeply nested. In other words there can be unions of differences or intersections of merges or differences of intersections or even unions of intersections of differences of merges... ad infinitum. CSG objects are (almost always) finite objects and thus respond to auto-bounding and can be transformed like any other POV primitive shape.

### Section 4.5.2
CSG Union

Let's try making a simple union. Create a file called csgdemo.pov and edit it as follows:

      #include "colors.inc"

      camera {
        location <0, 1, -10>
        look_at 0
        angle 36
      }

      light_source { <500, 500, -1000> White }

      plane { y, -1.5
        pigment { checker Green White }
      }

Let's add two spheres each translated 0.5 units along the x-axis in each direction. We color one blue and the other red.

      sphere { <0, 0, 0>, 1
        pigment { Blue }
        translate -0.5*x
      }
      sphere { <0, 0, 0>, 1
        pigment { Red }
        translate 0.5*x
      }

We trace this file at 200x150 -A. Now we place a union block around the two spheres. This will create a single CSG union out of the two objects.

      union{
        sphere { <0, 0, 0>, 1
          pigment { Blue }
          translate -0.5*x
        }
        sphere { <0, 0, 0>, 1
          pigment { Red }
          translate 0.5*x
        }
      }

We trace the file again. The union will appear no different from what each sphere looked like on its own, but now we can give the entire union a single texture and transform it as a whole. Let's do that now.

      union{
        sphere { <0, 0, 0>, 1
          translate -0.5*x*
        }
        sphere { <0, 0, 0>, 1
          translate 0.5*x
        }
        pigment { Red }
        scale <1, .25, 1>
        rotate <30, 0, 45>
      }

We trace the file again. As we can see, the object has changed dramatically. We experiment with different values of scale and rotate and try some different textures.

There are many advantages of assigning only one texture to a CSG object instead of assigning the texture to each individual component. First, it is much easier to use one texture if our CSG object has a lot of components because changing the objects appearance involves changing only one single texture. Second, the file parses faster because the texture has to be parsed only once. This may be a great factor when doing large scenes or animations. Third, using only one texture saves memory because the texture is only stored once and referenced by all components of the CSG object. Assigning the texture to all n components means that it is stored n times.

### Section 4.5.3
CSG Intersection

Now let's use these same spheres to illustrate the next kind of CSG object, the intersection. We change the word union to intersection and delete the scale and rotate statements:

      intersection {
        sphere { <0, 0, 0>, 1
          translate -0.5*x
        }
        sphere { <0, 0, 0>, 1
          translate 0.5*x
        }
        pigment { Red }
      }

We trace the file and will see a lens-shaped object instead of the two spheres. This is because an intersection consists of the area shared by both shapes, in this case the lens-shaped area where the two spheres overlap. We like this lens-shaped object so we will use it to demonstrate differences.

### Section 4.5.4
CSG Difference

We rotate the lens-shaped intersection about the y-axis so that the broad side is facing the camera.

      intersection{
        sphere { <0, 0, 0>, 1
          translate -0.5*x
        }
        sphere { <0, 0, 0>, 1
          translate 0.5*x
        }
        pigment { Red }
        rotate 90*y
      }

Let's create a cylinder and stick it right in the middle of the lens.

      cylinder { <0, 0, -1> <0, 0, 1>, .35
        pigment { Blue }
      }

We render the scene to see the position of the cylinder. We will place a difference block around both the lens-shaped intersection and the cylinder like this:

      difference {
        intersection {
          sphere { <0, 0, 0>, 1
            translate -0.5*x
          }
          sphere { <0, 0, 0>, 1
            translate 0.5*x
          }
          pigment { Red }
          rotate 90*y
        }
        cylinder { <0, 0, -1> <0, 0, 1>, .35
          pigment { Blue }
        }
      }

We render the file again and see the lens-shaped intersection with a neat hole in the middle of it where the cylinder was. The cylinder has been subtracted from the intersection. Note that the pigment of the cylinder causes the surface of the hole to be colored blue. If we eliminate this pigment the surface of the hole will be red.

OK, let's get a little wilder now. Let's declare our perforated lens object to give it a name. Let's also eliminate all textures in the declared object because we will want them to be in the final union instead.

      #declare Lens_With_Hole = difference {
        intersection {
          sphere { <0, 0, 0>, 1
            translate -0.5*x
          }
          sphere { <0, 0, 0>, 1
            translate 0.5*x
          }
          rotate 90*y
        }
        cylinder { <0, 0, -1> <0, 0, 1>, .35 }
      }

Let's use a union to build a complex shape composed of copies of this object.

      union {
        object { Lens_With_Hole translate <-.65, .65, 0> }
        object { Lens_With_Hole translate <.65, .65, 0> }
        object { Lens_With_Hole translate <-.65, -.65, 0> }
        object { Lens_With_Hole translate <.65, -.65, 0> }
        pigment { Red }
      }

We render the scene. An interesting object to be sure. But let's try something more. Let's make it a partially-transparent object by adding some filter to the pigment block.

      union {
        object { Lens_With_Hole translate <-.65, .65, 0> }
        object { Lens_With_Hole translate <.65, .65, 0> }
        object { Lens_With_Hole translate <-.65, -.65, 0> }
        object { Lens_With_Hole translate <.65, -.65, 0> }
        pigment { Red filter .5 }
      }

We render the file again. This looks pretty good... only... we can see parts of each of the lens objects inside the union! This is not good.

### Section 4.5.5
CSG Merge

This brings us to the fourth kind of CSG object, the merge. Merges are the same as unions, but the geometry of the objects in the CSG that is inside the merge is not traced. This should eliminate the problem with our object. Let's try it.

      merge {
        object { Lens_With_Hole translate <-.65, .65, 0> }
        object { Lens_With_Hole translate <.65, .65, 0> }
        object { Lens_With_Hole translate <-.65, -.65, 0> }
        object { Lens_With_Hole translate <.65, -.65, 0> }
        pigment { Red filter .5 }
      }

Sure enough, it does!

### Section 4.5.6
CSG Pitfalls

There is a severe pitfall in the CSG code that we have to be aware of.

### Section 4.5.6.1
Coincidence Surfaces

POV-Ray uses inside/outside tests to determine the points at which a ray intersects a CSG object. A problem arises when the surfaces of two different shapes coincide because there is no way (due to numerical problems) to tell whether a point on the coincident surface belongs to one shape or the other.

Look at the following example where a cylinder is used to cut a hole in a larger box.

      difference {
        box { -1, 1 pigment { Red } }
        cylinder { -z, z, 0.5 pigment { Green } }
      }

If we trace this object we see red speckles where the hole is supposed to be. This is caused by the coincident surfaces of the cylinder and the box. One time the cylinder's surface is hit first by a viewing ray, resulting in the correct rendering of the hole, and another time the box is hit first, leading to a wrong result where the hole vanishes and red speckles appear.

This problem can be avoided by increasing the size of the cylinder to get rid of the coincidence surfaces. This is done by:

      difference {
        box { -1, 1 pigment { Red } }
        cylinder { -1.001*z, 1.001*z, 0.5 pigment { Green } }
      }

In general we have to make the subtracted object a little bit larger in a CSG difference. We just have to look for coincident surfaces and increase the subtracted object appropriately to get rid of those surfaces.

The same problem occurs in CSG intersections and is also avoided by scaling some of the involved objects.

### Section 4.6
The Light Source

In any ray-traced scene, the light needed to illuminate our objects and their surfaces must come from a light source. There are many kinds of light sources available in POV-Ray and careful use of the correct kind can yield very impressive results. Let's take a moment to explore some of the different kinds of light sources and their various parameters.

### Section 4.6.1
The Ambient Light Source

The ambient light source is used to simulate the effect of inter-diffuse reflection. If there wasn't inter-diffuse reflection all areas not directly lit by a light source would be completely dark. POV-Ray uses the ambient keyword to determine how much light coming from the ambient light source is reflected by a surface.

By default the ambient light source, which emits its light everywhere and in all directions, is pure white (rgb <1,1,1>). Changing its color can be used to create interesting effects. First of all the overall light level of the scene can be adjusted easily. Instead of changing all ambient values in every finish only the ambient light source is modified. By assigning different colors we can create nice effects like a moody reddish ambient lighting. For more details about the ambient light source see "Ambient Light".

Below is an example of a red ambient light source.

      global_settings { ambient_light rgb<1, 0, 0> }

### Section 4.6.2
The Pointlight Source

Pointlights are exactly what the name indicates. A pointlight has no size, is invisible and illuminates everything in the scene equally no matter how far away from the light source it may be (this behavior can be changed). This is the simplest and most basic light source. There are only two important parameters, location and color. Let's design a simple scene and place a pointlight source in it.

We create a new file and name it litedemo.pov. We edit it as follows:

      #include "colors.inc"
      #include "textures.inc"

      camera {
        location  <-4, 3, -9>
        look_at   <0, 0, 0>
        angle 48
      }

We add the following simple objects:

      plane { y, -1
        texture {
          pigment {
            checker
            color rgb<0.5, 0, 0>
            color rgb<0, 0.5, 0.5>
          }
          finish {
            diffuse 0.4
            ambient 0.2
            phong 1
            phong_size 100
            reflection 0.25
          }
        }
      }

      torus { 1.5, 0.5
        texture { Brown_Agate }
        rotate <90, 160, 0>
        translate  <-1, 1, 3>
      }

      box { <-1, -1, -1>, <1, 1, 1>
        texture { DMFLightOak }
        translate  <2, 0, 2.3>
      }

      cone { <0,1,0>, 0, <0,0,0>, 1
        texture { PinkAlabaster }
        scale <1, 3, 1>
        translate  <-2, -1, -1>
      }

      sphere { <0,0,0>,1
        texture { Sapphire_Agate }
        translate  <1.5, 0, -2>
      }

Now we add a pointlight:

      light_source {
        <2, 10, -3>
        color White
      }

We render this at 200x150 -A and see that the objects are clearly visible with sharp shadows. The sides of curved objects nearest the light source are brightest in color with the areas that are facing away from the light source being darkest. We also note that the checkered plane is illuminated evenly all the way to the horizon. This allows us to see the plane, but it is not very realistic.

### Section 4.6.3
The Spotlight Source

Spotlights are a very useful type of light source. They can be used to add highlights and illuminate features much as a photographer uses spots to do the same thing. There are a few more parameters with spotlights than with pointlights. These are radius, falloff, tightness and point_at. The radius parameter is the angle of the fully illuminated cone. The falloff parameter is the angle of the umbra cone where the light falls off to darkness. The tightness is a parameter that determines the rate of the light falloff. The point_at parameter is just what it says, the location where the spotlight is pointing to. Let's change the light in our scene as follows:

      light_source {
        <0, 10, -3>
        color White
        spotlight
        radius 15
        falloff 20
        tightness 10
        point_at <0, 0, 0>
      }

We render this at 200x150 -A and see that only the objects are illuminated. The rest of the plane and the outer portions of the objects are now unlit. There is a broad falloff area but the shadows are still razor sharp. Let's try fiddling with some of these parameters to see what they do. We change the falloff value to 16 (it must always be larger than the radius value) and render again. Now the falloff is very narrow and the objects are either brightly lit or in total darkness. Now we change falloff back to 20 and change the tightness value to 100 (higher is tighter) and render again. The spotlight appears to have gotten much smaller but what has really happened is that the falloff has become so steep that the radius actually appears smaller.

We decide that a tightness value of 10 (the default) and a falloff value of 18 are best for this spotlight and we now want to put a few spots around the scene for effect. Let's place a slightly narrower blue and a red one in addition to the white one we already have:

      light_source {
        <10, 10, -1>
        color Red
        spotlight
        radius 12
        falloff 14
        tightness 10
        point_at <2, 0, 0>
      }

      light_source {
        <-12, 10, -1>
        color Blue
        spotlight
        radius 12
        falloff 14
        tightness 10
        point_at <-2, 0, 0>
      }

Rendering this we see that the scene now has a wonderfully mysterious air to it. The three spotlights all converge on the objects making them blue on one side and red on the other with enough white in the middle to provide a balance.

### Section 4.6.4
The Cylindrical Light Source

Spotlights are cone shaped, meaning that their effect will change with distance. The farther away from the spotlight an object is, the larger the apparent radius will be. But we may want the radius and falloff to be a particular size no matter how far away the spotlight is. For this reason, cylindrical light sources are needed. A cylindrical light source is just like a spotlight, except that the radius and falloff regions are the same no matter how far from the light source our object is. The shape is therefore a cylinder rather than a cone. We can specify a cylindrical light source by replacing the spotlight keyword with the cylinder keyword. We try this now with our scene by replacing all three spotlights with cylinder lights and rendering again. We see that the scene is much dimmer. This is because the cylindrical constraints do not let the light spread out like in a spotlight. Larger radius and falloff values are needed to do the job. We try a radius of 20 and a falloff of 30 for all three lights. That's the ticket!

Next Section
Table Of Contents